/*
-----------------------------------------------------------------------------
This source file is part of OpenSpace3D
For the latest info, see http://www.openspace3d.com

Copyright (c) 2012 I-maginer

This program is free software; you can redistribute it and/or modify it under
the terms of the GNU Lesser General Public License as published by the Free Software
Foundation; either version 2 of the License, or (at your option) any later
version.

This program is distributed in the hope that it will be useful, but WITHOUT
ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
FOR A PARTICULAR PURPOSE. See the GNU Lesser General Public License for more details.

You should have received a copy of the GNU Lesser General Public License along with
this program; if not, write to the Free Software Foundation, Inc., 59 Temple
Place - Suite 330, Boston, MA 02111-1307, USA, or go to
http://www.gnu.org/copyleft/lesser.txt

-----------------------------------------------------------------------------
*/

fun deleteOb(inst)=
  setPluginInstanceCbKeyDown inst nil;
  setPluginInstanceCbKeyUp inst nil;
  0;;


fun cbKeyDown(inst, viewstr, key, ascode, p)=
  let _keybdstate -> kbstate in
  let p -> [keyname state norepeat rstate] in
  let KEYBgetKeyNumber keyname -> ukey in
  if kbstate!=state then nil else
  if ((key != ukey) && !rstate) || (rstate && norepeat) then nil else
  (
    mutate p <- [_ _ _ 1];
    SendPluginEvent inst "Key down" nil inst.INST_sName;
  );
  0;;


fun cbKeyUp(inst, viewstr, key, p)=
  let _keybdstate -> kbstate in
  let p -> [keyname state norepeat rstate] in
  let KEYBgetKeyNumber keyname -> ukey in
  if kbstate!=state then nil else 
  if (key != ukey) then nil else
  (
    mutate p <- [_ _ _ 0];
    SendPluginEvent inst "Key up" nil inst.INST_sName;
  );
  0;;


fun cbSendKeyDown(inst, from, action, param, rep, p)=
  let (V3DgetSessionView c3dXsession) -> viewstr in
  let p -> [keyname state norepeat rstate] in
  (
    let KEYBgetKeyNumber keyname -> ukey in
      cbV3DviewKeyDown viewstr.V3D_win viewstr ukey nil;
  );
  0;; 


fun cbSendKeyUp(inst, from, action, param, rep, p)=
  let (V3DgetSessionView c3dXsession) -> viewstr in
  let p -> [keyname state norepeat rstate] in
  (
    let KEYBgetKeyNumber keyname -> ukey in
      cbV3DviewKeyUp viewstr.V3D_win viewstr ukey;
  );
  0;;


fun cbChangeKeyboardMode(inst, from, action, param, reply)=
  // retrieve the keyboard type in action name
  let substr action ((strlen (getPluginInstanceName inst)) + 1) (strlen action) -> action in
  let nth_list hd (strextr action) 1 -> keybtype in
    KEYBsetCurrentKeyboardType keybtype;
  0;;


fun newOb(inst)=
  let (getPluginInstanceParam inst "keyname") -> keyname in
  let atoi (getPluginInstanceParam inst "specialKey") -> specialKey in
  let getPluginInstanceParam inst "mode" -> modeName in
  let atoi (getPluginInstanceParam inst "norepeat") -> norepeat in
  let if norepeat == nil then 0 else norepeat -> norepeat in
  if keyname == nil then nil else
  let [keyname specialKey norepeat 0] -> p in
  (
    KEYBsetCurrentKeyboardType modeName;
    setPluginInstanceCbKeyDown inst mkfun5 @cbKeyDown p;
    setPluginInstanceCbKeyUp inst mkfun4 @cbKeyUp p;
    
    PluginRegisterAction inst "Send key down" mkfun6 @cbSendKeyDown p;
    PluginRegisterAction inst "Send key up" mkfun6 @cbSendKeyUp p;
    
    let getPluginInstanceUserActions inst -> laction in
    let sizelist laction -> size in
    let 0 -> i in
    while i < size do
    (
      let nth_list laction i -> act in
      if (strcmp "Set " (substr act 0 4)) then nil else
        PluginRegisterAction inst act @cbChangeKeyboardMode;
      
      set i = i + 1;
    );
    
    setPluginInstanceCbDel inst @deleteOb;
  );
  0;;


fun IniPlug(file)=
  PlugRegister @newOb nil;
  setPluginEditor @dynamicedit;
  0;;