/*
-----------------------------------------------------------------------------
This source file is part of OpenSpace3D
For the latest info, see http://www.openspace3d.com

Copyright (c) 2012 I-maginer

This program is free software; you can redistribute it and/or modify it under
the terms of the GNU Lesser General Public License as published by the Free Software
Foundation; either version 2 of the License, or (at your option) any later
version.

This program is distributed in the hope that it will be useful, but WITHOUT
ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
FOR A PARTICULAR PURPOSE. See the GNU Lesser General Public License for more details.

You should have received a copy of the GNU Lesser General Public License along with
this program; if not, write to the Free Software Foundation, Inc., 59 Temple
Place - Suite 330, Boston, MA 02111-1307, USA, or go to
http://www.gnu.org/copyleft/lesser.txt

-----------------------------------------------------------------------------
*/


fun cbCloseEdit(p)=
  let p -> [ctrlobjname ctrlmatname ctrlmattech ctrlmatpass ctrlmattex ctrlcamera ctrlsize ctrlscheme ctrlcompo ctrlauto ctrlinit] in
  let getEdCtrlTextLineValue ctrlobjname -> objname in
  let getSelectedEdCtrlSelect ctrlmatname -> matname in
  let getSelectedEdCtrlSelectPos ctrlmattech -> technique in
  let getSelectedEdCtrlSelectPos ctrlmatpass -> pass in
  let getSelectedEdCtrlSelectPos ctrlmattex -> texture in
  let getEdCtrlTextLineValue ctrlcamera -> camera in
  let getSelectedEdCtrlSelect ctrlsize -> size in
  let getSelectedEdCtrlSelect ctrlscheme -> scheme in
  let getSelectedEdCtrlSelect ctrlcompo -> compositor in
  let getEdCtrlCheckState ctrlauto -> auto in
  let getEdCtrlCheckState ctrlinit -> init in
    ["object" objname]::
    ["material" matname]::
    ["technique" itoa technique]::
    ["pass" itoa pass]::
    ["texture" itoa texture]::
    ["camera" camera]::
    ["size" size]::
    ["scheme" scheme]::
    ["compositor" compositor]::
    ["autoupdate" itoa auto]::
    ["init" itoa init]::
    nil;;


fun fillMaterialTextureSelector(viewstr, ctrlselect, mat, tech, pass)=
  if mat == nil then nil else
  let V3DgetDefaultSession viewstr -> sessionstr in
  let SO3MaterialNumberOfTexturesByTechniqueAndPass mat tech pass -> size in
  let 0 -> i in
  let nil -> lmatname in
  (
    while i < size do
    (
      let SO3MaterialTextureUnitGetNameByIndex mat tech pass i -> matname in
        set lmatname = lcat lmatname matname::nil;
      
      set i = i + 1;
    );
    
    fillEdCtrlSelect ctrlselect lmatname;
  );
  0;;


fun cbMatPassName(ctrlstr, pos, elem, p)=
  let p -> [inst viewstr group ctrlmatname ctrlmattech ctrlmattex] in
  let getSelectedEdCtrlSelectPos ctrlmattech -> tech in
  let getSelectedEdCtrlSelect ctrlmatname -> matname in
  let V3DgetDefaultSession viewstr -> sessionstr in
  let if matname != nil then SO3SceneGetMaterial (V3DgetSession sessionstr) group matname else nil -> mat in
    fillMaterialTextureSelector viewstr ctrlmattex mat tech pos;
  0;;


fun fillMaterialPassSelector(viewstr, p, mat, tech)=
  let p -> [ctrlselect ctrlmatname ctrlmattech ctrlmattex] in
  if mat == nil then nil else
  let V3DgetDefaultSession viewstr -> sessionstr in
  let SO3MaterialNumberOfPassesByTechnique mat tech -> size in
  let 0 -> i in
  let nil -> lmatname in
  (
    while i < size do
    (
      let SO3MaterialPassGetNameByIndex mat tech i -> matname in
      let if (!strcmp matname "") then (itoa i) else matname -> matname in
        set lmatname = lcat lmatname matname::nil;
      
      set i = i + 1;
    );
    
    fillEdCtrlSelect ctrlselect lmatname;
    fillMaterialTextureSelector viewstr ctrlmattex mat tech 0;
  );
  0;;


fun cbMatTechniqueName(ctrlstr, pos, elem, p)=
  let p -> [inst viewstr group ctrlmatname ctrlmatpass ctrlmattex] in
  let getSelectedEdCtrlSelect ctrlmatname -> matname in
  let V3DgetDefaultSession viewstr -> sessionstr in
  let if matname != nil then SO3SceneGetMaterial (V3DgetSession sessionstr) group matname else nil -> mat in
    fillMaterialPassSelector viewstr [ctrlmatpass ctrlmatname ctrlstr ctrlmattex] mat pos;
  0;;


fun fillMaterialTechSelector(viewstr, p, mat)=
  let p -> [ctrlselect ctrlmatname ctrlmatpass ctrlmattex] in
  if mat == nil then nil else
  let V3DgetDefaultSession viewstr -> sessionstr in
  let SO3MaterialNumberOfTechniques mat -> size in
  let 0 -> i in
  let nil -> lmatname in
  (
    while i < size do
    (
      let SO3MaterialTechniqueGetNameByIndex mat i -> matname in
        set lmatname = lcat lmatname matname::nil;
      
      set i = i + 1;
    );
    
    fillEdCtrlSelect ctrlselect lmatname;
    fillMaterialPassSelector viewstr [ctrlmatpass ctrlmatname ctrlselect ctrlmattex] mat 0;
  );
  0;;


fun cbMatName(ctrlstr, pos, elem, p)=
  let p -> [inst viewstr group ctrlmattech ctrlmatpass ctrlmattex] in
  let V3DgetDefaultSession viewstr -> sessionstr in
  let if elem != nil then SO3SceneGetMaterial (V3DgetSession sessionstr) group elem else nil -> mat in
    fillMaterialTechSelector viewstr [ctrlmattech ctrlstr ctrlmatpass ctrlmattex] mat;
  0;;


fun fillMaterialSelector(viewstr, p, objname)=
  let p -> [inst ctrlselect ctrlmattech ctrlmatpass ctrlmattex] in
  if objname == nil then nil else
  let V3DgetDefaultSession viewstr -> sessionstr in
  let SO3SceneGetObject (V3DgetSession sessionstr) objname -> obj in
  let SO3EntityGetResourceGroup obj -> group in
  let SO3EntityMaterialList obj -> lmat in
  let nil -> lmatname in
  (
    setEdCtrlSelectCb ctrlselect mkfun4 @cbMatName [inst viewstr group ctrlmattech ctrlmatpass ctrlmattex];
    setEdCtrlSelectCb ctrlmattech mkfun4 @cbMatTechniqueName [inst viewstr group ctrlselect ctrlmatpass ctrlmattex];
    setEdCtrlSelectCb ctrlmatpass mkfun4 @cbMatPassName [inst viewstr group ctrlselect ctrlmattech ctrlmattex];
    
    let sizelist lmat -> size in
    let 0 -> i in
    while i < size do
    (
      let nth_list lmat i -> mat in
      let SO3MaterialGetName mat -> matname in
        set lmatname = lcat lmatname matname::nil;
      
      set i = i + 1;
    );
    
    fillEdCtrlSelect ctrlselect lmatname;
    fillMaterialTechSelector viewstr [ctrlmattech ctrlselect ctrlmatpass ctrlmattex] (SO3SceneGetMaterial (V3DgetSession sessionstr) group (hd lmatname));
  );
  0;;
  

fun cbSelectObj(val, type, p)=
  let p -> [inst winstr viewstr ctrlobjname ctrlmatname ctrlmattech ctrlmatpass ctrlmattex] in
  let V3DgetDefaultSession viewstr -> sessionstr in
  let SO3SceneGetObject (V3DgetSession sessionstr) val -> obj in
  if obj == nil then nil else
  (
    setEdCtrlTextLineValue ctrlobjname val;
    fillMaterialSelector viewstr [inst ctrlmatname ctrlmattech ctrlmatpass ctrlmattex] val;
  );
  0;;


fun cbCloseRes(ctrlbtn)=
  setEdCtrlButtonEnable ctrlbtn 1;
  0;;


fun cbBtnPickObj(ctrlbtn, p)=
  let p -> [inst winstr viewstr ctrlobjname ctrlmatname ctrlmattech ctrlmatpass ctrlmattex objname] in
  (
    setEdCtrlButtonEnable ctrlbtn 0;
    dlgSelectPluginInstanceResource inst winstr iTypeEntity objname mkfun3 @cbSelectObj [inst winstr viewstr ctrlobjname ctrlmatname ctrlmattech ctrlmatpass ctrlmattex] mkfun1 @cbCloseRes ctrlbtn 0;
  );
  0;;


fun cbSelectCam(val, type, p)=
  let p -> [inst winstr viewstr ctrlobjname] in
  let V3DgetDefaultSession viewstr -> sessionstr in
  let SO3SceneGetObject (V3DgetSession sessionstr) val -> obj in
  if (obj != nil) || (!strcmpi "Current camera" val) then
  (
    setEdCtrlTextLineValue ctrlobjname val;
  )
  else nil;
  0;;


fun cbBtnPickCam(ctrlbtn, p)=
  let p -> [inst winstr viewstr ctrlobjname objname] in
  (
    setEdCtrlButtonEnable ctrlbtn 0;
    dlgSelectPluginInstanceResource inst winstr iTypeCamera objname mkfun3 @cbSelectCam [inst winstr viewstr ctrlobjname] mkfun1 @cbCloseRes ctrlbtn 0;
  );
  0;;


fun cbRefreshBtn(pickbtn, p)=
  let p -> [ctrlobjname] in
  setEdCtrlTextLineValue ctrlobjname "";
0;;


fun cbRefreshBtnSpec(pickbtn, p)=
  let p -> [ctrlobjname ctrlmatname ctrlmattech ctrlmatpass ctrlmattex] in
  (
    setEdCtrlTextLineValue ctrlobjname "";

    fillEdCtrlSelect ctrlmatname nil;
    fillEdCtrlSelect ctrlmattech nil;
    fillEdCtrlSelect ctrlmatpass nil;
    fillEdCtrlSelect ctrlmattex nil;
  );
  0;;
  
  
fun dynamicedit(ewinstr, inst, viewstr, applybtn)=
  let [455 370] -> [iw ih] in
  let 10 -> ypos in
  (
    setEdWindowSize ewinstr iw ih;
    let (getPluginInstanceParam inst "object") -> objname in
    let (getPluginInstanceParam inst "material") -> matname in
    let atoi (getPluginInstanceParam inst "technique") -> technique in
    let if technique == nil then 0 else technique -> technique in
    let atoi (getPluginInstanceParam inst "pass") -> pass in
    let if pass == nil then 0 else pass -> pass in
    let atoi (getPluginInstanceParam inst "texture") -> texture in
    let if texture == nil then 0 else texture -> texture in
    let (getPluginInstanceParam inst "camera") -> camera in
    let atoi (getPluginInstanceParam inst "size") -> size in
    let if size == nil then 256 else size -> size in
    let (getPluginInstanceParam inst "scheme") -> scheme in
    let if scheme == nil then "Default" else scheme -> scheme in
    let (getPluginInstanceParam inst "compositor") -> compositor in
    let if compositor == nil then "" else compositor -> compositor in
    
    let atoi (getPluginInstanceParam inst "autoupdate") -> auto in
    let if auto == nil then 1 else auto -> auto in    
    let atoi (getPluginInstanceParam inst "init") -> init in
    let if init == nil then 1 else init -> init in    
    
    let crEdFrameWindow _channel ewinstr 0 0 iw 155 EDWIN_RESIZE_MW nil (loc "OS3DCAMERATEXTURE_0007") (loc "OS3DCAMERATEXTURE_0009") -> winfrm in
    let crEdWindow _channel winfrm 0 18 iw 145 WN_CHILDINSIDE|WN_NOBORDER EDWIN_RESIZE_MW nil nil -> winstr in
    let crEdCtrlLabel winstr 10 (ypos + 2) 170 20 (loc "OS3DCAMERATEXTURE_0011") nil -> labelobj in
    let crEdCtrlTextLine winstr 180 ypos 170 20 objname nil EDWIN_RESIZE_MW -> ctrlobjname in
    let crEdCtrlButton winstr 360 ypos 55 20 "..." nil -> pickbtn in
    let crEdCtrlButton winstr 420 ypos 35 20 "X" nil -> refreshobjname in

    let crEdCtrlLabel winstr 10 ((set ypos = ypos + 25) + 2) 170 20 (loc "OS3DCAMERATEXTURE_0006") nil -> labelmat in
    let crEdCtrlSelect winstr 180 ypos (iw - 180) 120 EDWIN_RESIZE_MW -> ctrlmatname in
    let crEdCtrlLabel winstr 10 ((set ypos = ypos + 25) + 2) 170 20 (loc "OS3DCAMERATEXTURE_0008") nil -> labeltech in
    let crEdCtrlSelect winstr 180 ypos (iw - 180) 120 EDWIN_RESIZE_MW -> ctrlmattech in
    let crEdCtrlLabel winstr 10 ((set ypos = ypos + 25) + 2) 170 20 (loc "OS3DCAMERATEXTURE_0013") nil -> labelpass in
    let crEdCtrlSelect winstr 180 ypos (iw - 180) 120 EDWIN_RESIZE_MW -> ctrlmatpass in
    let crEdCtrlLabel winstr 10 ((set ypos = ypos + 25) + 2) 170 20 (loc "OS3DCAMERATEXTURE_0012") nil -> labelpass in
    let crEdCtrlSelect winstr 180 ypos (iw - 180) 120 EDWIN_RESIZE_MW -> ctrlmattex in
    
    let crEdFrameWindow _channel ewinstr 0 0 iw 155 EDWIN_RESIZE_MW nil (loc "OS3DCAMERATEXTURE_0004") (loc "OS3DCAMERATEXTURE_0009") -> winfrm in
    let crEdWindow _channel winfrm 0 18 iw 135 WN_CHILDINSIDE|WN_NOBORDER EDWIN_RESIZE_MW nil nil -> winstr in
    let crEdCtrlLabel winstr 10 ((set ypos = 10) + 2) 160 20 (loc "OS3DCAMERATEXTURE_0003") nil -> labelcam in
    let crEdCtrlTextLine winstr 180 ypos 140 20 camera nil EDWIN_RESIZE_MW -> ctrlcamera in
    let crEdCtrlButton winstr 325 ypos 55 20 "..." nil -> pickcam in
    let crEdCtrlButton winstr 385 ypos 35 20 "X" nil -> refreshcam in
    let crEdCtrlLabel winstr 10 ((set ypos = ypos + 25) + 2) 170 20 (loc "OS3DCAMERATEXTURE_0014") nil -> labelsize in
    let crEdCtrlSelect winstr 180 ypos 200 120 EDWIN_RESIZE_MW -> ctrlsize in
    let crEdCtrlLabel winstr 10 ((set ypos = ypos + 25) + 2) 160 20 (loc "OS3DCAMERATEXTURE_0015") nil -> labelscheme in
    let crEdCtrlSelect winstr 180 ypos (iw - 190) 120 CB_AHSCROLL -> ctrlscheme in
    let crEdCtrlLabel winstr 10 ((set ypos = ypos + 25) + 2) 160 20 (loc "OS3DCAMERATEXTURE_0016") nil -> labelcompo in
    let crEdCtrlSelect winstr 180 ypos (iw - 190) 120 CB_AHSCROLL -> ctrlcompo in
    let crEdCtrlCheck winstr 10 (set ypos = ypos + 25) 280 20 (loc "OS3DCAMERATEXTURE_0002") EDWIN_RESIZE_MW -> ctrlauto in
    
    let crEdFrameWindow _channel ewinstr 0 0 iw 55 EDWIN_RESIZE_MW nil (loc "OS3DCAMERATEXTURE_0010") (loc "OS3DCAMERATEXTURE_0009") -> winfrm in
    let crEdWindow _channel winfrm 0 18 iw 35 WN_CHILDINSIDE|WN_NOBORDER EDWIN_RESIZE_MW nil nil -> winstr in
    let crEdCtrlCheck winstr 10 (set ypos = 10) 280 20 (loc "OS3DCAMERATEXTURE_0001") EDWIN_RESIZE_MW -> ctrlinit in
    
    let V3DgetDefaultSession viewstr -> sessionstr in
    let SO3SceneGetObject (V3DgetSession sessionstr) objname -> obj in
    let SO3EntityGetResourceGroup obj -> group in
    (
      setEdCtrlCheckState ctrlinit init;
      setEdCtrlCheckState ctrlauto auto;
      
      fillEdCtrlSelect ctrlsize "64"::"128"::"256"::"512"::"1024"::"2048"::nil;
      selectEdCtrlSelect ctrlsize itoa size;
      
      fillEdCtrlSelect ctrlscheme (getAllMaterialScheme viewstr);
      selectEdCtrlSelect ctrlscheme scheme;
      
      let lcat (V3DgetDefaultCompositorsList sessionstr) (SO3SceneParseCompositorsFromGroup (V3DgetSession sessionstr) "Scene") -> lcompname in
      let lcat ""::nil 
        let nil -> nl in
        (
          let sizelist lcompname -> size in
          let 0 -> i in
          while i < size do
          (
            let nth_list lcompname i -> compname in
            set nl = compname::nl;
            
            set i = i + 1;
          );
          quicksort nl @suppDoublon
        )
      -> lcompname in
      
      fillEdCtrlSelect ctrlcompo lcompname;
      selectEdCtrlSelect ctrlcompo compositor;
      
      setEdCtrlButtonCb pickbtn mkfun2 @cbBtnPickObj [inst winstr viewstr ctrlobjname ctrlmatname ctrlmattech ctrlmatpass ctrlmattex objname];
      setEdCtrlTextLineEnable ctrlobjname 0;
      setEdCtrlButtonCb refreshobjname mkfun2 @cbRefreshBtnSpec [ctrlobjname ctrlmatname ctrlmattech ctrlmatpass ctrlmattex];
      
      fillMaterialSelector viewstr [inst ctrlmatname ctrlmattech ctrlmatpass ctrlmattex] objname;
      selectEdCtrlSelect ctrlmatname matname;
      
      setEdCtrlButtonCb pickcam mkfun2 @cbBtnPickCam [inst winstr viewstr ctrlcamera camera];
      setEdCtrlTextLineEnable ctrlcamera 0;
      setEdCtrlButtonCb refreshcam mkfun2 @cbRefreshBtn [ctrlcamera];      
      
      let SO3SceneGetMaterial (V3DgetSession sessionstr) group matname -> mat in
      if mat == nil then nil else
      (
        fillMaterialTechSelector viewstr [ctrlmattech ctrlmatname ctrlmatpass ctrlmattex] mat;
        selectEdCtrlSelectByPos ctrlmattech technique;
        
        fillMaterialPassSelector viewstr [ctrlmatpass ctrlmatname ctrlmattech ctrlmattex] mat technique;
        selectEdCtrlSelectByPos ctrlmatpass pass;
        
        fillMaterialTextureSelector viewstr ctrlmattex mat technique pass;
        selectEdCtrlSelectByPos ctrlmattex texture;
      );
      
      [mkfun1 @cbCloseEdit [ctrlobjname ctrlmatname ctrlmattech ctrlmatpass ctrlmattex ctrlcamera ctrlsize ctrlscheme ctrlcompo ctrlauto ctrlinit] nil];
    );
  );;