/*
-----------------------------------------------------------------------------
This source file is part of OpenSpace3D
For the latest info, see http://www.openspace3d.com

Copyright (c) 2014 I-maginer

This program is free software; you can redistribute it and/or modify it under
the terms of the GNU Lesser General Public License as published by the Free Software
Foundation; either version 2 of the License, or (at your option) any later
version.

This program is distributed in the hope that it will be useful, but WITHOUT
ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
FOR A PARTICULAR PURPOSE. See the GNU Lesser General Public License for more details.

You should have received a copy of the GNU Lesser General Public License along with
this program; if not, write to the Free Software Foundation, Inc., 59 Temple
Place - Suite 330, Boston, MA 02111-1307, USA, or go to
http://www.gnu.org/copyleft/lesser.txt

-----------------------------------------------------------------------------
*/

fun cbCloseEdit(p)=
  let p -> [ctrlobjname ctrlmsize ctrlenv ctrldragndrop] in
  let getEdCtrlTextLineValue ctrlobjname -> objname in
  let getEdCtrlFloatValue ctrlmsize -> msize in
  let getEdCtrlCheckState ctrlenv -> env in
  let getEdCtrlCheckState ctrldragndrop -> dragndrop in
    ["object" objname]::
    ["maxsize" ftoa msize]::
    ["env" itoa env]::
    ["dragndrop" itoa dragndrop]::
    nil;;


fun cbSelectObj(val, type, p)=
  let p -> [inst winstr viewstr ctrlobjname] in
  let V3DgetDefaultSession viewstr -> sessionstr in
  let SO3SceneGetObject (V3DgetSession sessionstr) val -> obj in
  if (obj != nil) || (!strcmpi "Current camera" val) || (!strcmpi "Current camera shell" val) then
  (
    setEdCtrlTextLineValue ctrlobjname val;
  )
  else nil;
  0;;


fun cbCloseRes(ctrlbtn)=
  setEdCtrlButtonEnable ctrlbtn 1;
  0;;


fun cbBtnPickObj(ctrlbtn, p)=
  let p -> [inst winstr viewstr ctrlobjname objname] in
  (
    setEdCtrlButtonEnable ctrlbtn 0;
    dlgSelectPluginInstanceResource inst winstr iTypeGroup|iTypeEntity|iTypeNode|iTypeLight|iTypeBone|iTypeCamera|iTypeParticle|iTypeCubeMap objname mkfun3 @cbSelectObj [inst winstr viewstr ctrlobjname] mkfun1 @cbCloseRes ctrlbtn 0;
  );
  0;;


fun cbRefreshBtn(pickbtn, p)=
  let p -> [ctrlobjname] in
  setEdCtrlTextLineValue ctrlobjname "";
0;;


fun dynamicedit(winstr, inst, viewstr, applybtn)=
  let [420 115] -> [iw ih] in
  let 10 -> ypos in
  (
    setEdWindowSize winstr iw ih;
    let (getPluginInstanceParam inst "object") -> objname in
    let atof (getPluginInstanceParam inst "maxsize") -> msize in
    let if msize == nil then 0.0 else msize -> msize in
    let atoi (getPluginInstanceParam inst "env") -> env in
  let if env == nil then 1 else env -> env in
    let atoi (getPluginInstanceParam inst "dragndrop") -> dragndrop in
    let if dragndrop == nil then 0 else dragndrop -> dragndrop in

    let crEdCtrlLabel winstr 10 ypos + 2 185 20 (loc "OS3DSCENELOADER_0004") nil -> labelobj in
    let crEdCtrlTextLine winstr 180 ypos 165 20 objname nil EDWIN_RESIZE_MW -> ctrlobjname in
    let crEdCtrlButton winstr 325 ypos 55 20 "..." nil -> pickbtn in
    let crEdCtrlButton winstr 385 ypos 35 20 "X" nil -> refreshobjname in
    let crEdCtrlLabel winstr ypos ((set ypos = ypos + 25) + 2) 160 20 (loc "OS3DSCENELOADER_0003") nil -> labelmsize in
    let crEdCtrlFloat winstr 180 ypos 100 20 msize 0.0 1000000.0 0.01 3 nil EDWIN_RESIZE_MW -> ctrlmsize in
    let crEdCtrlCheck winstr 10 (set ypos = ypos + 25) 280 20 (loc "OS3DSCENELOADER_0006") EDWIN_RESIZE_MW -> ctrlenv in
    let crEdCtrlCheck winstr 10 (set ypos = ypos + 25) 280 20 (loc "OS3DSCENELOADER_0005") EDWIN_RESIZE_MW -> ctrldragndrop in
    (
      setEdCtrlButtonCb pickbtn mkfun2 @cbBtnPickObj [inst winstr viewstr ctrlobjname objname];
      setEdCtrlTextLineEnable ctrlobjname 0;
      setEdCtrlButtonCb refreshobjname mkfun2 @cbRefreshBtn [ctrlobjname];
      setEdCtrlCheckState ctrlenv env;
      setEdCtrlCheckState ctrldragndrop dragndrop;
      
      [mkfun1 @cbCloseEdit [ctrlobjname ctrlmsize ctrlenv ctrldragndrop] nil];
    );
  );;