/*
-----------------------------------------------------------------------------
This source file is part of OpenSpace3D
For the latest info, see http://www.openspace3d.com

Copyright (c) 2012 I-maginer

This program is free software; you can redistribute it and/or modify it under
the terms of the GNU Lesser General Public License as published by the Free Software
Foundation; either version 2 of the License, or (at your option) any later
version.

This program is distributed in the hope that it will be useful, but WITHOUT
ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
FOR A PARTICULAR PURPOSE. See the GNU Lesser General Public License for more details.

You should have received a copy of the GNU Lesser General Public License along with
this program; if not, write to the Free Software Foundation, Inc., 59 Temple
Place - Suite 330, Boston, MA 02111-1307, USA, or go to
http://www.gnu.org/copyleft/lesser.txt

-----------------------------------------------------------------------------
*/

struct SwitchStr = [
  PSWITCH_position    	  : I,
  PSWITCH_bInputOnChange  : I,
  PSWITCH_sLeftState      : S,
  PSWITCH_sRightState     : S
  
  ] MkSwitchStr;;

fun deleteOb(inst)=
  0;;


fun cbInput(inst, from, action, param, rep, obstr) =
  if (!obstr.PSWITCH_position) then
    SendPluginEvent inst (capitalizeFirstLetter obstr.PSWITCH_sLeftState) param nil
  else
    SendPluginEvent inst (capitalizeFirstLetter obstr.PSWITCH_sRightState) param nil;
  0;;
  

fun cbSwitchLeft(inst, from, action, param, rep, obstr) =
  if (!obstr.PSWITCH_bInputOnChange || !obstr.PSWITCH_position) then nil else
    SendPluginEvent inst (capitalizeFirstLetter obstr.PSWITCH_sLeftState) param nil;
  set obstr.PSWITCH_position = 0;
  0;;


fun cbSwitchRight(inst, from, action, param, rep, obstr) =
  if (!obstr.PSWITCH_bInputOnChange || obstr.PSWITCH_position) then nil else
    SendPluginEvent inst (capitalizeFirstLetter obstr.PSWITCH_sRightState) param nil;
  set obstr.PSWITCH_position = 1;
  0;;


fun cbSwitchToggle(inst, from, action, param, rep, obstr) =
  set obstr.PSWITCH_position = !obstr.PSWITCH_position;
  if (!obstr.PSWITCH_bInputOnChange) then
    nil 
  else if (!obstr.PSWITCH_position) then
    SendPluginEvent inst (capitalizeFirstLetter obstr.PSWITCH_sLeftState) param nil
  else
    SendPluginEvent inst (capitalizeFirstLetter obstr.PSWITCH_sRightState) param nil;
  0;;


fun newOb(inst)=
  let (getPluginInstanceParam inst "lstate") -> lstate in
  let if (lstate == nil) then "left" else lstate -> lstate in
  let (getPluginInstanceParam inst "rstate") -> rstate in
  let if (rstate == nil) then "right" else rstate -> rstate in
  let (getPluginInstanceParam inst "pos") -> spos in
  let if (spos == nil) then 0 else if !strcmpi spos "Left" then 0 else if !strcmpi spos "Right" then 1 else atoi spos -> pos in
  let atoi (getPluginInstanceParam inst "inputonchange") -> inputonchange in
  let if inputonchange == nil then 0 else inputonchange -> inputonchange in
  
  let MkSwitchStr [pos inputonchange lstate rstate] -> obstr in
  (
    PluginRegisterAction inst "Input" mkfun6 @cbInput obstr;
    PluginRegisterAction inst strcat "Switch " lstate mkfun6 @cbSwitchLeft obstr;
    PluginRegisterAction inst strcat "Switch " rstate mkfun6 @cbSwitchRight obstr;
    PluginRegisterAction inst "Toggle" mkfun6 @cbSwitchToggle obstr;
    
    setPluginInstanceCbDel inst @deleteOb;
  );
  0;;


fun IniPlug(file)=
  PlugRegister @newOb nil;
  setPluginEditor @dynamicedit;
  0;;