/*
-----------------------------------------------------------------------------
This source file is part of OpenSpace3D
For the latest info, see http://www.openspace3d.com

Copyright (c) 2012 I-maginer

This program is free software; you can redistribute it and/or modify it under
the terms of the GNU Lesser General Public License as published by the Free Software
Foundation; either version 2 of the License, or (at your option) any later
version.

This program is distributed in the hope that it will be useful, but WITHOUT
ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
FOR A PARTICULAR PURPOSE. See the GNU Lesser General Public License for more details.

You should have received a copy of the GNU Lesser General Public License along with
this program; if not, write to the Free Software Foundation, Inc., 59 Temple
Place - Suite 330, Boston, MA 02111-1307, USA, or go to
http://www.gnu.org/copyleft/lesser.txt

-----------------------------------------------------------------------------
*/


fun deleteOb(inst)=
  setPluginInstanceCbPostRender inst nil;
  0;;


fun cbGetDistance(inst, viewstr, p)=
  let p -> [object1 object2 iobj1mode iobj2mode dist debounce interv state bcurdist enable] in
  if (!enable) then nil else
  (
    let if (iobj1mode != 0) then
        (
          let V3DgetDefaultCamera c3dXsession -> curcamera in
            V3DgetCameraByType c3dXsession curcamera iobj1mode;
        )
        else
          object1
    -> object1 in
    let if (iobj2mode != 0) then
        (
          let V3DgetDefaultCamera c3dXsession -> curcamera in
            V3DgetCameraByType c3dXsession curcamera iobj2mode;
        )
        else
          object2
    -> object2 in
    if (object1 == nil || object2 == nil) then nil else
    let SO3ObjectGetGlobalPosition object1 -> [ox oy oz] in
    let SO3ObjectGetGlobalPosition object2 -> [cx cy cz] in
    let sqrt ((sqr(cx -. ox)) +. (sqr(cy -. oy)) +. (sqr(cz -. oz))) -> cdist in
    (
      if (!bcurdist) then nil else
        SendPluginEvent inst "Current distance" ftoa cdist nil;
      
      if (cdist <. dist) && (!state) then
      (
        mutate p <- [_ _ _ _ _ _ _tickcount 1 _ _];
        SendPluginEvent inst "In" nil nil;
      )
      else if (cdist >=. dist) && (state) && ((interv == nil) || (_tickcount - interv >= debounce)) then
      (
        mutate p <- [_ _ _ _ _ _ _ 0 _ _];
        SendPluginEvent inst "Out" nil nil;
      )
      else nil;
    );
  );
  0;;


fun cbEnable(inst, from, action, param, rep, p)=
  let p -> [_ _ _ _ _ _ _ _ _ enable] in
  if (enable) then nil else
    mutate p <- [_ _ _ _ _ _ nil 0 _ 1];
  0;;


fun cbDisable(inst, from, action, param, rep, p)=
  let p -> [_ _ _ _ _ _ _ _ _ enable] in
  if (!enable) then nil else
    mutate p <- [_ _ _ _ _ _ nil 0 _ 0];
  0;;


fun cbSetFirstObject(inst, from, action, param, reply, p)=
  let V3DgetObjectByName c3dXsession param -> obj in
  let V3DgetObjectTypeByName param -> iobjmode in
  if (obj == nil) then nil else
		mutate p <- [obj _ iobjmode _ _ _ _ _ _ _];
  0;;


fun cbSetSecondObject(inst, from, action, param, reply, p)=
  let V3DgetObjectByName c3dXsession param -> obj in
  let V3DgetObjectTypeByName param -> iobjmode in
  if (obj == nil) then nil else
		mutate p <- [_ obj _ iobjmode _ _ _ _ _ _];
  0;;


fun newOb(inst)=
  let (getPluginInstanceParam inst "object") -> objname1 in
  let (getPluginInstanceParam inst "object2") -> objname2 in
  // for compatibility
  let if ((atoi (getPluginInstanceParam inst "iscamera")) == 1) then "Current camera" else objname2 -> objname2 in

  let atof (getPluginInstanceParam inst "distance") -> dist in
  let if dist == nil then 1.0 else dist -> dist in
  let atoi (getPluginInstanceParam inst "debounce") -> debounce in
  let if debounce == nil then 0 else debounce -> debounce in
  let atoi (getPluginInstanceParam inst "init") -> init in
  let if init == nil then 1 else init -> init in
  
  let V3DgetObjectByName c3dXsession objname1 -> object1 in
  let V3DgetObjectTypeByName objname1 -> iobj1mode in
  let V3DgetObjectByName c3dXsession objname2 -> object2 in
  let V3DgetObjectTypeByName objname2 -> iobj2mode in
 
  let (IsInEditor inst) || IsEventLinked inst "Current distance" -> bcurdist in
  let [object1 object2 iobj1mode iobj2mode dist debounce nil 0 bcurdist init] -> p in
  (
    setPluginInstanceCbPostRender inst mkfun3 @cbGetDistance p;
    
    PluginRegisterAction inst "Enable" mkfun6 @cbEnable p;
	  PluginRegisterAction inst "Disable" mkfun6 @cbDisable p;
	  PluginRegisterAction inst "Set first object" mkfun6 @cbSetFirstObject p;
	  PluginRegisterAction inst "Set second object" mkfun6 @cbSetSecondObject p;
    
    setPluginInstanceCbDel inst @deleteOb;
  );
  0;;


fun IniPlug(file)=
  PlugRegister @newOb nil;
  setPluginEditorInstanceCb @dynamicinit @dynamicdelete @dynamicstart @dynamicstop;
  setPluginEditor @dynamicedit;
  0;;