/*
-----------------------------------------------------------------------------
This source file is part of OpenSpace3D
For the latest info, see http://www.openspace3d.com

Copyright (c) 2012 I-maginer

This program is free software; you can redistribute it and/or modify it under
the terms of the GNU Lesser General Public License as published by the Free Software
Foundation; either version 2 of the License, or (at your option) any later
version.

This program is distributed in the hope that it will be useful, but WITHOUT
ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
FOR A PARTICULAR PURPOSE. See the GNU Lesser General Public License for more details.

You should have received a copy of the GNU Lesser General Public License along with
this program; if not, write to the Free Software Foundation, Inc., 59 Temple
Place - Suite 330, Boston, MA 02111-1307, USA, or go to
http://www.gnu.org/copyleft/lesser.txt

-----------------------------------------------------------------------------
*/


fun deleteOb(inst)=
  0;;


fun removeId(objname)=
  let strfind "." objname 0 -> pos in
  if (pos == nil) then
    objname
  else
    substr objname (pos + 1) ((strlen objname) - pos - 1);;


fun searchObjectInHierarchy(name)=
  let SO3ObjectGetChildren (SO3ObjectGetSceneRoot (V3DgetSession c3dXsession)) -> l in
  let nil -> found in
  (
    while (l != nil && found == nil) do
    (
      let hd l -> obj in
      let removeId (SO3ObjectGetName obj) -> objname in
      if ((strcmpi name objname) == 0) then
      (
        set found = obj;
        0;
      )
      else
      (
        set l = lcat (tl l) (SO3ObjectGetChildren obj);
        0;
      );
    );
    found;
  );;


fun cbSetObjectName(inst, from, action, param, reply, p)=
  let strtrim param -> search in
  let V3DgetObjectByName c3dXsession search -> obj in
  if (obj != nil) then
  (
    mutate p <- [search];
  )
  else
  (
    let searchObjectInHierarchy search -> obj in
    let SO3ObjectGetName obj -> name in
      mutate p <- [name];
  );
  0;;


fun cbGetObject(inst, from, action, param, reply, p)=
  let p -> [name] in
  let V3DgetObjectByName c3dXsession name -> obj in
  let SO3ObjectGetName obj -> name in
    SendPluginEvent inst "Object" name nil;
  0;;


fun cbGetObjectInit(inst, p)=
  cbGetObject inst nil nil nil nil p;
  0;;


fun newOb(inst)=
  let (getPluginInstanceParam inst "object") -> objname in
  let atoi (getPluginInstanceParam inst "init") -> init in
  let if init == nil then 0 else init -> init in
  let [objname] -> p in
  (
    if (!init) then
      nil 
    else if inst.INST_groupstr.GRP_project.PRJ_bPluginsLoaded then
    (
      cbGetObject inst nil nil nil nil p;
      0;
    )
    else
    (
      setPluginInstanceCbAllPluginsLoaded inst mkfun2 @cbGetObjectInit p;
      0;
    );
  
    PluginRegisterAction inst "Get object" mkfun6 @cbGetObject p;
    PluginRegisterAction inst "Set object name" mkfun6 @cbSetObjectName p;
    
    setPluginInstanceCbDel inst @deleteOb;
  );
  0;;


fun IniPlug(file)=
  PlugRegister @newOb nil;
  setPluginEditor @dynamicedit;
  0;;