/*
-----------------------------------------------------------------------------
This source file is part of OpenSpace3D
For the latest info, see http://www.openspace3d.com

Copyright (c) 2012 I-maginer

This program is free software; you can redistribute it and/or modify it under
the terms of the GNU Lesser General Public License as published by the Free Software
Foundation; either version 2 of the License, or (at your option) any later
version.

This program is distributed in the hope that it will be useful, but WITHOUT
ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
FOR A PARTICULAR PURPOSE. See the GNU Lesser General Public License for more details.

You should have received a copy of the GNU Lesser General Public License along with
this program; if not, write to the Free Software Foundation, Inc., 59 Temple
Place - Suite 330, Boston, MA 02111-1307, USA, or go to
http://www.gnu.org/copyleft/lesser.txt

-----------------------------------------------------------------------------
*/

  

fun deleteOb(inst)=
  0;;


fun mapData(input, vmin, vmax, tmin, tmax)=
  let if input >. vmax then vmax else input -> input in
  let if input <. vmin then vmin else input -> input in
  (input -. vmin) *. (tmax -. tmin) /. (vmax -. vmin) +. tmin;;


fun cbMap(inst, from, action, param, reply, p)=
  let p -> [imin imax omin omax] in
  let strextr param -> lp in
  let nil -> np in
  (
    while lp != nil do
    (
      let hd lp -> line in
      let nil -> nline in
      (
        while line != nil do
        (
          let hd line -> elem in
          let atof elem -> pval in
          let if pval == nil then elem else (ftoa (mapData pval imin imax omin omax)) -> nelem in
            set nline = lcat nline nelem::nil;
          
          set line = tl line;
        );
        
        set np = lcat np (strcatnSep nline " ")::nil;
      );
      set lp = tl lp;
    );

    SendPluginEvent inst "Out" (strcatnSep np "\n") nil;
  );
  0;;


fun newOb(inst)=
  let atof (getPluginInstanceParam inst "inmin") -> inmin in
  let atof (getPluginInstanceParam inst "inmax") -> inmax in
  let atof (getPluginInstanceParam inst "outmin") -> outmin in
  let atof (getPluginInstanceParam inst "outmax") -> outmax in
  if (inmin == inmax) || (outmin == outmax) then nil else
  (
    PluginRegisterAction inst "In" mkfun6 @cbMap [inmin inmax outmin outmax];
  );
  
  setPluginInstanceCbDel inst @deleteOb;
  0;;


fun IniPlug(file)=
  srand time;
  PlugRegister @newOb nil;
  setPluginEditor @dynamicedit;
  0;;