/*
-----------------------------------------------------------------------------
This source file is part of OpenSpace3D
For the latest info, see http://www.openspace3d.com

Copyright (c) 2016 I-maginer

This program is free software; you can redistribute it and/or modify it under
the terms of the GNU Lesser General Public License as published by the Free Software
Foundation; either version 2 of the License, or (at your option) any later
version.

This program is distributed in the hope that it will be useful, but WITHOUT
ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
FOR A PARTICULAR PURPOSE. See the GNU Lesser General Public License for more details.

You should have received a copy of the GNU Lesser General Public License along with
this program; if not, write to the Free Software Foundation, Inc., 59 Temple
Place - Suite 330, Boston, MA 02111-1307, USA, or go to
http://www.gnu.org/copyleft/lesser.txt

-----------------------------------------------------------------------------
*/

/*
  Version : 1.0
  First version : 05/29/2016
  Author : Bourineau Bastien
*/

fun getActions(nb)=
  let nil -> ndata in
  let 0 -> i in
  (
    while i < nb do
    (
      set ndata = ["ACTION" strcat "Set value on " (itoa (i + 1))]::ndata;
      set i = i + 1;
    );
    ndata;
  );;

/*! \brief Callback on plugIT instance editor closed
  *
  *  <b>Prototype:</b> fun [] [[S S] r1]
  *   
  *  \return [[S S] r1] : parameters to save in the instance XML data
  **/
fun cbCloseEdit(p)=
  let p -> [ctrldevice ctrlfreq ctrlservos ctrlinit] in
  let getEdCtrlTextLineValue ctrldevice -> device in
  let itoa ftoi getEdCtrlFloatValue ctrlfreq -> freq in
  let itoa getEdCtrlCheckState ctrlservos -> servos in
  let itoa getEdCtrlCheckState ctrlinit -> init in
  ["device" device]::
  ["frequency" freq]::
  ["forServos" servos]::
  ["init" init]::
  (getActions 16);;


/*! \brief Callback on plugIT instance editor opened
  *
  *  <b>Prototype:</b> fun [EdWindow PInstance V3Dview] I
  *
  *  \param EdWindow : editor window structure
  *  \param PInstance : plugIT instance
  *  \param V3Dview : default 3D view structure
  *  
  *  \return @fun [] [[S S] r1] : Callback to call on close
  **/
fun dynamicedit(winstr, inst, viewstr, applybtn)=
  let [400 110] -> [iw ih] in
  (
    setEdWindowSize winstr iw ih;
    let getPluginInstanceParam inst "i2cdevice" -> i2cdevice in
    let if i2cdevice == nil then "0x40" else i2cdevice -> i2cdevice in
    let itof atoi (getPluginInstanceParam inst "frequency") -> frequency in
    let if frequency == nil then 50.0 else frequency -> frequency in
    let atoi (getPluginInstanceParam inst "forServos") -> forServos in
    let if forServos == nil then 1 else forServos -> forServos in
    let atoi (getPluginInstanceParam inst "init") -> init in
    let if init == nil then 1 else init -> init in
    
    let 10 -> ypos in
    let crEdCtrlLabel winstr 10 ypos + 2 160 20 (loc "OS3DGPIO9685_0001") nil -> labeldata in
    let crEdCtrlTextLine winstr 180 ypos 90 20 i2cdevice nil EDWIN_RESIZE_MW -> ctrldevice in
    let crEdCtrlLabel winstr 10 (set ypos = ypos + 25) + 2 160 20 (loc "OS3DGPIO9685_0002") nil -> labelfreq in
    let crEdCtrlFloat winstr 180 ypos 130 20 frequency 0.0 1000.0 1.0 0 nil EDWIN_RESIZE_MW -> ctrlfreq in
    let crEdCtrlCheck winstr 10 (set ypos = ypos + 25) 280 20 (loc "OS3DGPIO9685_0003") EDWIN_RESIZE_MW -> ctrlservos in
    let crEdCtrlCheck winstr 10 (set ypos = ypos + 25) 280 20 (loc "OS3DGPIO9685_0004") EDWIN_RESIZE_MW -> ctrlinit in
    (
      setEdCtrlCheckState ctrlservos forServos;
      setEdCtrlCheckState ctrlinit init;
      
      [mkfun1 @cbCloseEdit [ctrldevice ctrlfreq ctrlservos ctrlinit] nil];
    );
  );;