/*
-----------------------------------------------------------------------------
This source file is part of OpenSpace3D
For the latest info, see http://www.openspace3d.com

Copyright (c) 2016 I-maginer

This program is free software; you can redistribute it and/or modify it under
the terms of the GNU Lesser General Public License as published by the Free Software
Foundation; either version 2 of the License, or (at your option) any later
version.

This program is distributed in the hope that it will be useful, but WITHOUT
ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
FOR A PARTICULAR PURPOSE. See the GNU Lesser General Public License for more details.

You should have received a copy of the GNU Lesser General Public License along with
this program; if not, write to the Free Software Foundation, Inc., 59 Temple
Place - Suite 330, Boston, MA 02111-1307, USA, or go to
http://www.gnu.org/copyleft/lesser.txt

-----------------------------------------------------------------------------
*/

/*
  Version : 1.0
  First version : 05/29/2016
  Author : Bourineau Bastien
*/


/*! \brief Callback on plugIT instance editor closed
  *
  *  <b>Prototype:</b> fun [] [[S S] r1]
  *   
  *  \return [[S S] r1] : parameters to save in the instance XML data
  **/
fun cbCloseEdit(p)=
  let p -> [ctrlpin ctrlmode ctrlinit ctrlinitvalue] in
    let (getSelectedEdCtrlSelect ctrlpin) -> pin in
    let getSelectedEdCtrlSelectPos ctrlmode -> mode in
    let itoa (getSelectedEdCtrlSelectPos ctrlinit) -> init in
    let itoa (ftoi (getEdCtrlFloatValue ctrlinitvalue)) -> initval in
    let if mode == 0 then init else initval -> defval in
    ["pin" pin]::
    ["mode" itoa mode]::
    ["initvalue" defval]::
    nil;;


fun cbSelectMode(ctrl, pos, elem, p)=
  let p -> [ctrlinit ctrlinitvalue] in
  if (pos == 0) then
  (
    setEdCtrlFloatEnable ctrlinitvalue 0;
    setEdCtrlSelectEnable ctrlinit 1;
  )
  else
  (
    setEdCtrlSelectEnable ctrlinit 0;    
    setEdCtrlFloatEnable ctrlinitvalue 1;
  );
  0;;


/*! \brief Callback on plugIT instance editor opened
  *
  *  <b>Prototype:</b> fun [EdWindow PInstance V3Dview] I
  *
  *  \param EdWindow : editor window structure
  *  \param PInstance : plugIT instance
  *  \param V3Dview : default 3D view structure
  *  
  *  \return @fun [] [[S S] r1] : Callback to call on close
  **/
fun dynamicedit(winstr, inst, viewstr, applybtn)=
  let [400 115] -> [iw ih] in
  (
    setEdWindowSize winstr iw ih;
    let atoi (getPluginInstanceParam inst "pin") -> pin in
    let if pin == nil then 2 else pin -> pin in
    let atoi (getPluginInstanceParam inst "mode") -> mode in
    let if mode == nil then 0 else mode -> mode in
    let atoi (getPluginInstanceParam inst "initvalue") -> initvalue in
    let if initvalue == nil then 0 else initvalue -> initvalue in
    
    let 10 -> ypos in
    let crEdCtrlLabel winstr 10 ypos + 2 160 20 (loc "OS3DGPIOOUT_0001") nil -> labeltitle in
    let crEdCtrlSelect winstr 180 ypos 200 130 EDWIN_RESIZE_MW -> ctrlpin in
    let crEdCtrlLabel winstr 10 (set ypos = ypos + 25) + 2 160 20 (loc "OS3DGPIOOUT_0002") nil -> labelmode in
    let crEdCtrlSelect winstr 180 ypos 200 130 EDWIN_RESIZE_MW -> ctrlmode in
    let crEdCtrlLabel winstr 10 (set ypos = ypos + 25) + 2 160 20 (loc "OS3DGPIOOUT_0003") nil -> labelinit in
    let crEdCtrlSelect winstr 180 ypos 200 130 EDWIN_RESIZE_MW -> ctrlinit in
    let crEdCtrlLabel winstr 10 (set ypos = ypos + 25) + 2 160 20 (loc "OS3DGPIOOUT_0004") nil -> labelinitval in
    let crEdCtrlFloat winstr 180 ypos 110 20 itof initvalue 0.0 1023.0 1.0 0 nil EDWIN_RESIZE_MW -> ctrlinitvalue in
    (
    	let 2 -> i in
    	while i < 28 do
    	(
      	addEdCtrlSelect ctrlpin itoa i;
      	set i = i + 1;
     	);
      selectEdCtrlSelect ctrlpin itoa pin;
      
      fillEdCtrlSelect ctrlmode "Digital"::"Analogic"::"PWM"::nil;
      selectEdCtrlSelectByPos ctrlmode mode;
      setEdCtrlSelectCb ctrlmode mkfun4 @cbSelectMode [ctrlinit ctrlinitvalue];
      
      fillEdCtrlSelect ctrlinit "Low"::"High"::nil;
      selectEdCtrlSelectByPos ctrlinit initvalue;
      
      if (mode == 0) then
      (
        setEdCtrlFloatEnable ctrlinitvalue 0;
      )
      else
      (
        setEdCtrlSelectEnable ctrlinit 0;
      );      
      
      [mkfun1 @cbCloseEdit [ctrlpin ctrlmode ctrlinit ctrlinitvalue] nil];
    );
  );;