/*
-----------------------------------------------------------------------------
This source file is part of OpenSpace3D
For the latest info, see http://www.openspace3d.com

Copyright (c) 2012 I-maginer

This program is free software; you can redistribute it and/or modify it under
the terms of the GNU Lesser General Public License as published by the Free Software
Foundation; either version 2 of the License, or (at your option) any later
version.

This program is distributed in the hope that it will be useful, but WITHOUT
ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
FOR A PARTICULAR PURPOSE. See the GNU Lesser General Public License for more details.

You should have received a copy of the GNU Lesser General Public License along with
this program; if not, write to the Free Software Foundation, Inc., 59 Temple
Place - Suite 330, Boston, MA 02111-1307, USA, or go to
http://www.gnu.org/copyleft/lesser.txt

-----------------------------------------------------------------------------
*/

fun cbDestroyEdit()= 0;;

fun cbCloseEdit(p)=
let p -> [ctrlobjname ctrlbias ctrlinit] in
  let getEdCtrlTextLineValue ctrlobjname -> objname in
  let ftoa getEdCtrlFloatValue ctrlbias -> bias in
  let getEdCtrlCheckState ctrlinit -> init in
    ["camera" objname]::
    ["bias" bias]::
    ["init" itoa init]::
    nil;;


fun cbSelectObj(val, type, p)=
  let p -> [inst winstr viewstr ctrlobjname] in
  let V3DgetDefaultSession viewstr -> sessionstr in
  let SO3SceneGetObject (V3DgetSession sessionstr) val -> obj in
  if (obj != nil) || (!strcmpi "Current camera" val) || (!strcmpi "Current camera shell" val) then
  (
    setEdCtrlTextLineValue ctrlobjname val;
  )
  else nil;
  0;;


fun cbCloseRes(ctrlbtn)=
  setEdCtrlButtonEnable ctrlbtn 1;
  0;;


fun cbBtnPickObj(ctrlbtn, p)=
  let p -> [inst winstr viewstr ctrlobjname objname] in
  (
    setEdCtrlButtonEnable ctrlbtn 0;
    dlgSelectPluginInstanceResource inst winstr iTypeCamera objname mkfun3 @cbSelectObj [inst winstr viewstr ctrlobjname] mkfun1 @cbCloseRes ctrlbtn 0;
  );
  0;;


fun cbRefreshBtn(pickbtn, p)=
  let p -> [ctrlobjname] in
  setEdCtrlTextLineValue ctrlobjname "";
0;;


fun dynamicedit(winstr, inst, viewstr, applybtn)=
  let [420 90] -> [iw ih] in
  (
    setEdWindowSize winstr iw ih;
    
    let (getPluginInstanceParam inst "camera") -> objname in
    let atoi (getPluginInstanceParam inst "init") -> init in
    let if init == nil then 1 else init -> init in
    let atof (getPluginInstanceParam inst "bias") -> bias in
    let if bias == nil then 1.0 else bias -> bias in
    
    let crEdCtrlLabel winstr 10 12 160 20 (loc "OS3DLODBIAS_0001") nil -> labelobj in
    let crEdCtrlTextLine winstr 180 10 140 20 objname nil EDWIN_RESIZE_MW -> ctrlobjname in
    let crEdCtrlButton winstr 325 10 55 20 "..." nil -> pickbtn in
    let crEdCtrlButton winstr 385 10 35 20 "X" nil -> refreshobjname in    
    let crEdCtrlLabel winstr 10 37 160 20 (loc "OS3DLODBIAS_0002") nil -> labelbias in
    let crEdCtrlFloat winstr 180 35 100 20 bias 0.0001 100.0 0.01 4 nil EDWIN_RESIZE_MW -> ctrlbias in
    let crEdCtrlCheck winstr 10 60 280 20 (loc "OS3DLODBIAS_0003") EDWIN_RESIZE_MW -> ctrlinit in
    (
      setEdCtrlCheckState ctrlinit init;
      
      setEdCtrlButtonCb pickbtn mkfun2 @cbBtnPickObj [inst winstr viewstr ctrlobjname objname];
      setEdCtrlTextLineEnable ctrlobjname 0;
      setEdCtrlButtonCb refreshobjname mkfun2 @cbRefreshBtn [ctrlobjname];
      [mkfun1 @cbCloseEdit [ctrlobjname ctrlbias ctrlinit] nil];
    );
  );;